<%
'	//*******************  Information  ***********************
'	//	Program Title	:	접속통계 config
'	//	File Name		  :	config.asp
'	//							  : 
'	//*********************************************************
'
'	//*******************  Information  ***********************
'	// 함수설명 : 이전,다음) 년,월,일 변경
'	//*********************************************************
	sub ChangeDate( prevTextYY, nextTextYY, prevTextMM, nextTextMM, prevTextDD, nextTextDD)

		if YY <> "" Then theCase = "YY"
		
		if YY <> "" and MM <> "" Then theCase = "MM"
		
		if YY <> "" and MM <> "" and DD <> "" Then theCase = "DD"
		'//echo $theCase;
		Select Case theCase
			Case "YY"
				tempPrev = YY - 1
				tempNext = YY + 1

				if tempPrev < 1 Then tempPrev = 1

				if tempNext > 2100 Then tempNext = 2100

				strValue = "&nbsp;<a href='" & Request.ServerVariables("path_info") & "?YY=" & tempPrev & "'>" & prevTextYY & "</a>&nbsp;|&nbsp;"
				strValue = strValue & "<a href='" & Request.ServerVariables("path_info") & "?YY=" & tempNext & "'>" & nextTextYY & "</a>"
			Case "MM"
				tempPrev = DateSerial(YY, MM-1, 1)
				tempNext = DateSerial(YY, MM+1, 1)

				strValue = "&nbsp;<a href='" & Request.ServerVariables("path_info") & "?YY=" & year(tempPrev) & "&MM=" & Right( "0" & Month(tempPrev), 2 ) & "'>" & prevTextMM & "</a>&nbsp;|&nbsp;"
				strValue = strValue & "<a href='" & Request.ServerVariables("path_info") & "?YY=" & Year( tempNext ) & "&MM=" & Right( "0" & Month( tempNext ), 2 ) & "'>" & nextTextMM & "</a>"

			Case "DD"

				tempPrev = DateSerial(YY, MM, DD-1)
				tempNext = DateSerial(YY, MM, DD+1)

				strValue = "&nbsp;<a href='" & Request.ServerVariables("path_info") & "?YY=" & Year(tempPrev) & "&MM=" & Right( "0" & Month(tempPrev), 2 ) & "&DD=" & Right( "0" & Day(tempPrev), 2 ) & "'>" & prevTextDD & "</a>&nbsp;|&nbsp;"
				strValue = strValue & "<a href='" & Request.ServerVariables("path_info") & "?YY=" & Year(tempNext) & "&MM=" & Right( "0" & Month(tempNext), 2) & "&DD=" & Right( "0" & Day(tempNext), 2 ) & "'>" & nextTextDD & "</a>"

		End select

		response.write strValue

	End sub

'	//*******************  Information  ***********************
'	// 함수설명 : 최대값 bold 적용
'	//*********************************************************
	sub SetDetail(theNum) 

		if arrData(theNum,0) = maxCount and maxCount <> 0 then
			arrData(theNum,0) = "<strong>" & arrData(theNum,0) & "</strong>"
		End if
		response.write arrData(theNum,0)

	End sub

'	//*******************  Information  ***********************
'	// 함수설명 : 주일
'	//*********************************************************
	sub SetWeek(theNum)
		Dim week
		Select Case theNum
			Case 0 :	week = "日"
			Case 1 :	week = "月"
			Case 2 :	week = "火"
			Case 3 :	week = "水"
			Case 4 :	week = "木"
			Case 5 :	week = "金"
			Case 6 :	week = "土"

		End select

		response.write week
	End sub


'	//*******************  Information  ***********************
'	// 함수설명 : os명
'	//*********************************************************
	function SetOS(strvalue)
		Dim vOS
		Select Case strvalue
			case "" :	vOS = "unKnown"
			case "Windows NT 5.0": vOS = "Windows 2000"
			case "Windows NT 5.1": vOS = "Windows XP"
			Case Else
				vOS = strvalue
		End select
		SetOS = vOS
	End function

'	//*******************  Information  ***********************
'	// 함수설명 : 브라우저명
'	//*********************************************************
	function SetBrowser(strvalue)
		if trim(strvalue) = "" then
			vBrowser = "unKnown"
		else
			vBrowser = strvalue
		End if

		SetBrowser = vBrowser
	End function

'	//*******************  Information  ***********************
'	// 함수설명 : 검색 조건
'	//*********************************************************
	sub SetWhere()
		
		qryValue = ""

		if YY <> "" then
			qryValue = " where vYY = '"& YY & "'"
		End if

		if MM <> "" then
			if qryValue <> "" then qryValue = qryValue & " and "
			qryValue = qryValue & " vMM = '" & MM & "'"
		End if

		if DD <> "" then
			if qryValue <> "" then qryValue = qryValue & " and "
			qryValue = qryValue & " vDD = '"& DD & "'"
		End if

		If YY = "" and ( MM <> "" or DD <> "" ) Then qryValue = " where " & qryValue

	End sub


'	//*******************  Information  ***********************
'	// 함수설명 : 년 select box
'	//*********************************************************
	sub SelectYear()
%>
	<select name="YY" onchange="document.Form1.submit();">
		<option value="">전체</option>
		<% for y = Year(now)-5 to Year(now) + 5 %>
		<option value="<%=y%>"><%=y%>년</option>
		<%next%>
	</select>
<%
	End sub

'	//*******************  Information  ***********************
'	// 함수설명 : 월 select box
'	//*********************************************************
	sub SelectMonth()
%>
	<select name="MM" onchange="document.Form1.submit();">
		<option value="">전체</option>
		<% For m = 1 To 12
			m = Right( "0" & m, 2 )
		%>
		<option value="<%=m%>"><%=m%>월</option>
		<% next%>
	</select>
<%
	End sub
  
'	//*******************  Information  ***********************
'	// 함수설명 : 일 select box
'	//*********************************************************
	sub SelectDay()
%>
	<select name="DD" onchange="document.Form1.submit();">
		<option value="">전체</option>
		<% For d = 1 To 31
			d = Right( "0" & d, 2 )
		%>
		<option value="<%=d%>"><%=d%>일</option>
		<% Next %>
	</select>
<%
	end sub
%>