<%


'//파라미터정보 *************************************************************************************
b_num		= InputValue(request("b_num"))
b_type		= InputValue(request("b_type"))
'//**************************************************************************************************


'//조회수 추가
sql = "update " & a_tablename & " set b_count = b_count + 1 Where b_num = " & b_num
dbcon.execute sql


'//레코드필드
R_Fields = "b_num, b_type, b_id, b_name, b_pwd, b_subject, b_email, b_jumin, b_phone1, b_phone2, b_phone3, b_cate, b_catename, b_noticechk, b_content, b_ip, b_count, b_look, b_open, b_ref, b_step, b_level, b_regdate, b_chuchun, b_sbjclr, b_sdate, b_edate, b_temp1, b_temp2, b_temp3, b_temp4, b_keyword, b_c_count"
' 첨부파일
If Not IsNumeric(a_upload_len) Then a_upload_len = 5
For u=1 To a_upload_len
	R_Fields = R_Fields & ", b_file"&u			'' b_file1, b_file2, b_file3, ‥‥
Next
R_tablename_str		= a_tablename
R_WHERE_str			= " WHERE b_num=" & b_num

Call SelectQuery (R_Fields, R_tablename_str, R_WHERE_str)





If is_ad_cms <> "Y" then	'//관리자가아닐때 체크

	'//공개/비공개 체크*************************************************************************************
	if a_type = "Y" Or a_type = "T" then	'//공개여부 사용일때

		If b_open = "N" Or a_type = "T" then	'//비공개일때

			If SESSION("pwd_chk_" & a_num & "_" & b_num) <> "ok" then
				Call locationhref( "pwd.asp?prepage=vie&a_num=" & a_num & "&b_num=" & b_num & "&" & page_info)
			End if

		End if

	End if
	'//**************************************************************************************************

End if

If a_edit = "N" then		'//에디터 사용하지 않을때...

	b_content	= getTextmode(b_content)

End if


'//이전글  ------------------------------------------------------------------------------------------------
sql_p_opt1 = " WHERE b_look = 'Y' AND b_num <> " & b_num & " AND b_ref <= " & b_ref & " AND b_step >=" & b_step
sql_p_orderby = " ORDER BY b_ref DESC, b_step ASC"


'//답변글 사용하지 않을때..적용
If a_reply = "N" then sql_p_opt2 = " AND b_type='N'"

sql_p = "SELECT top 1 b_num, b_subject FROM " & a_tablename
sql_p = sql_p & sql_p_opt1 & sql_p_opt2 & sql_p_orderby
Set rs_prev = dbcon.execute( sql_p )

If rs_prev.bof Or rs_prev.eof then
	prev_b_num = ""
else
	prev_b_num		= rs_prev("b_num")
	prev_b_subject	= rs_prev("b_subject")
End If
Set rs_prev = nothing

'//이전글끝  ------------------------------------------------------------------------------------------------



'//다음글  ------------------------------------------------------------------------------------------------
sql_p_opt1 = " WHERE b_look = 'Y' AND b_num <> " & b_num & " AND b_ref >= " & b_ref & " AND b_step <=" & b_step
sql_p_orderby = " ORDER BY b_ref ASC, b_step DESC"


'//답변글 사용하지 않을때..적용
If a_reply = "N" then sql_p_opt2 = " AND b_type='N'"

sql_p = "SELECT top 1 b_num, b_subject FROM " & a_tablename
sql_p = sql_p & sql_p_opt1 & sql_p_opt2 & sql_p_orderby
Set rs_next = dbcon.execute( sql_p )

If rs_next.bof Or rs_next.eof then
	next_b_num = ""
else
	next_b_num		= rs_next("b_num")
	next_b_subject	= rs_next("b_subject")
End If

Set rs_next = nothing

'//다음글끝  ------------------------------------------------------------------------------------------------




%>
<!--#include virtual="/content/board/top.asp"-->

<!-- 보기 -->
<div id="board" style="width:<%=a_width%>;">
	<!-- 보기 테이블 -->
	<div class="table_bview">

			<table cellspacing="0" >
			<caption><%=replace( tit_name, " | ", "")%></caption>
				<colgroup>
				<col width="6" />
				<col width="" />
				<col width="6" />
				</colgroup>
			<thead>
				<tr>
					<th scope="col" class="th_start"></th>
					<th scope="col" class="th_none"><%
					If b_type="N" And a_cate = "Y" then
						response.write "<span class='category_color'>"& b_cate_str(b_cate) & "</span>"
					End If
					response.write b_subject
					%></th>
					<th scope="col" class="th_end"></th>
				</tr>
			</thead>
			<tbody>
				<tr>
					<td></td>
					<td>
						<dl class="info">
							<dt>작성일</dt>
							<dd><%=b_regdate%></dd>
							<dt>작성자</dt>
							<dd><%=b_name%></dd>
							<dt>조회</dt>
							<dd><%=b_count%></dd>
						</dl>
					</td>
					<td></td>
				</tr>
				<%
				'//사용자필드
				for z=1 To 4
					a_ftemp		= eval("a_ftemp" & z )
					a_ftemp_str	= eval("a_ftemp" & z & "_str")
					b_temp		= eval("b_temp" & z )

					If a_ftemp = "Y" then
				%>
				<tr>
					<td></td>
					<td>
						<dl class="info">
							<dt><%=a_ftemp_str%></dt>
							<dd><%=b_temp%></dd>
						</dl>
					</td>
					<td></td>
				</tr>

				<%
					End if
				next
				%>

				<%If a_upload = "Y" and (b_file1 <> "" or b_file2 <> "" or b_file3 <> "" or b_file4 <> "" or b_file5 <> "" ) then	'//첨부파일 사용일때{%>
				<tr>
					<td></td>
					<td>
						<dl class="info">
							<dt>첨부파일</dt>
							<dd>
								<%
									For z=1 To a_upload_len
										b_file_name = eval("b_file" & z)
										b_file_name_tmp = b_file_name

										If b_file_name <> "" Then	'//파일이 있으면..

											strDir		= server.mappath("/data/board/") & "\" & a_tablename & "\"
											'response.write b_file_name
								%>

									<img src="/content/board/nninc_simple/img/file/<%=get_FileName1(b_file_name_tmp)%>" alt="<%=b_file_name%>" /><a href="down.asp?a_tablename=<%=a_tablename%>&amp;filename=<%=b_file_name%>"><%=b_file_name%></a> <span class="size">(<%=Folderfilesize(strDir& b_file_name)%> byte)</span>
									&nbsp;

								<%
										End if
									next
								%>
							</dd>
						</dl>
					</td>
					<td></td>
				</tr>
				<%End if%>
				<tr>
					<td colspan="3" class="content">
						<%
						
							tp_dir = "/data/board/" & a_tablename & "/"
					
							For z = 1 To a_upload_len

								b_file_name = eval("b_file" & z)
								b_file_name_tmp = b_file_name

								If b_file_name <> "" then
									tot_file = tp_dir & b_file_name

									If lcase(right(b_file_name_tmp,3)) = "gif" Or lcase(right(b_file_name_tmp,3)) = "jpg" then
						%>
							<a href = "<%=tot_file%>" rel="lightbox"><img src="<%=tot_file%>"  alt="<%=b_file_name%> 이미지를 클릭하시면 원본크기를 보실 수 있습니다." onload="imgResize(this, 500, 500);" width = "500"/></a><br />
						<%
									End if
								End if
							next
						%>
						<%=b_content%>
					</td>
				</tr>
			</tbody>
			</table>

	</div>
	<!-- //보기 테이블 -->

	<!-- 버튼 -->


	<div class="board_button">
		<div class="fl pt10">
			<%If next_b_num <> "" then%>
			<a href="view.asp?a_num=<%=a_num%>&amp;b_num=<%=next_b_num%>&amp;<%=page_info%>" ><img src="/content/board/nninc_simple/img/listup_bt.gif" width="18" height="18" alt="다음글" /></a>
			<%End if%>
			<%If prev_b_num <> "" then%>
			<a href="view.asp?a_num=<%=a_num%>&amp;b_num=<%=prev_b_num%>&amp;<%=page_info%>" ><img src="/content/board/nninc_simple/img/listdown_bt.gif" width="18" height="18" alt="이전글" /></a>
			<%End if%>
		</div>
		<div class="fr pt10">
			

			<%If is_reply = "Y" And a_reply = "Y" then '//답변%>
			<span><a href="write.asp?a_num=<%=a_num%>&amp;b_num=<%=b_num%>&amp;b_type=R&amp;<%=page_info%>" ><img src="/content/board/nninc_simple/img/reply_bt.gif" width="62" height="23" alt="답변" /></a></span>
			<%End if%>
			
			<%If is_write = "Y" then '//쓰기/수정권한%>
			<span><a href="write.asp?a_num=<%=a_num%>" ><img src="/content/board/nninc_simple/img/write_bt.gif" width="62" height="23" alt="쓰기" /></a></span>

			<span><a href="write.asp?a_num=<%=a_num%>&amp;b_num=<%=b_num%>&amp;<%=page_info%>" ><img src="/content/board/nninc_simple/img/modify_bt.gif" width="62" height="23" alt="수정" /></a></span>
			<%End if%>
			
			<%If is_delete = "Y" then
				msg = "정말 삭제하시겠습니까?"
				querystring = "msg=" & server.urlencode( msg )
				querystring = querystring & "&ok=" & server.urlencode("/content/board/delete_ok.asp?a_num=" & a_num & "&b_num=" & b_num & "&" & page_info)
				querystring = querystring & "&no=" & server.urlencode(nowpage)
				go_url = "/content/board/message.asp?a_num=" & a_num & "&amp;" & querystring
			%>
			<span><a href="<%=go_url%>" ><img src="/content/board/nninc_simple/img/delete_bt.gif" width="62" height="23" alt="삭제" /></a></span>
			<%End if%>

			<span><a href="list.asp?a_num=<%=a_num%>&amp;<%=page_info%>" ><img src="/content/board/nninc_simple/img/list_bt.gif" width="62" height="23" alt="목록" /></a></span>
		</div>
	</div>
	<!-- //버튼 -->




	<!-- 댓글 -->
	<%If a_command = "Y" Then%>
	<!--#include virtual="/content/board/command.asp"-->
	<%End if%>
	<!-- //댓글 -->

</div>
<!-- //보기 -->
<!--#include virtual="/content/board/bottom.asp"-->


</body>
</html>
